Учебники

Arduino — управление мышью

Март 4, 2019

Используя библиотеку Mouse, вы можете управлять экранным курсором компьютера с помощью Arduino Leonardo, Micro или Due.

В этом конкретном примере используются пять кнопок для перемещения экранного курсора. Четыре кнопки направлены (вверх, вниз, влево, вправо), а одна — для щелчка левой кнопкой мыши. Движение курсора от Arduino всегда относительно. Каждый раз, когда ввод читается, позиция курсора обновляется относительно его текущей позиции.

Всякий раз, когда нажимается одна из кнопок со стрелками, Arduino перемещает мышь, отображая HIGH-вход в диапазон от 5 в соответствующем направлении.

Пятая кнопка предназначена для управления левым щелчком мыши. Когда кнопка отпущена, компьютер распознает событие.

Необходимые компоненты

Вам понадобятся следующие компоненты —

  • 1 × макет
  • 1 × Arduino Leonardo, Micro или Due Board
  • Резистор 5 × 10 кОм
  • 5 × мгновенные кнопки

Процедура

Следуйте электрической схеме и подключите компоненты на макете, как показано на рисунке ниже.

Макет кнопки мыши

эскиз

Откройте программное обеспечение Arduino IDE на своем компьютере. Кодирование на языке Arduino будет контролировать вашу схему. Откройте новый файл эскиза, нажав Новый.

Для этого примера вам нужно использовать Arduino IDE 1.6.7

эскиз

Arduino Code 

/*
   Button Mouse Control
   For Leonardo and Due boards only .Controls the mouse from 
   five pushbuttons on an Arduino Leonardo, Micro or Due.
   Hardware:
   * 5 pushbuttons attached to D2, D3, D4, D5, D6
   The mouse movement is always relative. This sketch reads
   four pushbuttons, and uses them to set the movement of the mouse.
   WARNING: When you use the Mouse.move() command, the Arduino takes
   over your mouse! Make sure you have control before you use the mouse commands.
*/

#include "Mouse.h"
// set pin numbers for the five buttons:
const int upButton = 2;
const int downButton = 3;
const int leftButton = 4;
const int rightButton = 5;
const int mouseButton = 6;
int range = 5; // output range of X or Y movement; affects movement speed
int responseDelay = 10; // response delay of the mouse, in ms

void setup() {
   // initialize the buttons' inputs:
   pinMode(upButton, INPUT);
   pinMode(downButton, INPUT);
   pinMode(leftButton, INPUT);
   pinMode(rightButton, INPUT);
   pinMode(mouseButton, INPUT);
   // initialize mouse control:
   Mouse.begin();
}

void loop() {
   // read the buttons:
   int upState = digitalRead(upButton);
   int downState = digitalRead(downButton);
   int rightState = digitalRead(rightButton);
   int leftState = digitalRead(leftButton);
   int clickState = digitalRead(mouseButton);
   // calculate the movement distance based on the button states:
   int xDistance = (leftState - rightState) * range;
   int yDistance = (upState - downState) * range;
   // if X or Y is non-zero, move:
   if ((xDistance != 0) || (yDistance != 0)) {
      Mouse.move(xDistance, yDistance, 0);
   }

   // if the mouse button is pressed:
   if (clickState == HIGH) {
      // if the mouse is not pressed, press it:
      if (!Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.press(MOUSE_LEFT);
      }
   } else {                           // else the mouse button is not pressed:
      // if the mouse is pressed, release it:
      if (Mouse.isPressed(MOUSE_LEFT)) {
         Mouse.release(MOUSE_LEFT);
      }
   }
   // a delay so the mouse does not move too fast:
   delay(responseDelay);
}

Код для заметки

Подключите плату к компьютеру с помощью кабеля micro-USB. Кнопки подключены к цифровым входам от контактов 2 до 6. Убедитесь, что используются резисторы 10 кОм.

74
Share: