Инъекция зависимостей на Цейлоне со сваркой

Я лично сомневаюсь в преимуществах внедрения зависимости. С одной стороны, я признаю его полезность в определенных контейнерных средах, таких как Java EE. (Кстати, я был автором спецификации CDI 1.0 с моей группой экспертов JCP.) С другой стороны, учитывая характер того, над чем я работал последние несколько лет, у меня нет использование для этого в моих собственных программах.

Но есть много людей, которые клянутся через инъекцию зависимости и спрашивают меня, что Цейлон предлагает в этой области. Краткий ответ: ничего особенного; Цейлонский SDK построен вокруг понятия модульных библиотек. Он не предлагает ни рамки, ни контейнера. Это делает SDK настолько универсальным, насколько это возможно, то есть его можно повторно использовать из любой другой контейнерной среды (скажем, Java EE, vert.x, OSGi или любой другой).

Так что если вы хотите внедрить зависимости в Ceylon сегодня, вам придется использовать контейнер, написанный на Java. К счастью, Ceylon 1.2 обладает таким превосходным взаимодействием с Java, что это практически не приводит к трениям. Конечно , кто — то будет писать зависимость инъекционного контейнера на Цейлоне нибудь , но, как мы о том, чтобы увидеть, нет никакой срочности вообще.

Я собираюсь исследовать:

• Weld , эталонная реализация CDI, разработанная моими коллегами из Red Hat, и,
• в интересах предоставления равного времени «конкуренту», Google Guice , первоначально написанный моим другом Бобом Ли, который оказал одно из основных влияний на спецификацию CDI.

Это мои любимые контейнеры для Java, хотя, конечно, у Spring есть легионы фанатов. Возможно, я найду время поиграть с ним в другой день.

Вы можете найти пример кода в следующем Git-репозитории:

https://github.com/ceylon/ceylon-examples-di

сваривать

Мне было очень просто использовать сварку на Цейлоне, за исключением одной относительно небольшой проблемы, о которой я расскажу ниже.

Модуль дескриптора для сварки

Weld предоставляет толстую банку в Maven Central, что делает его особенно простым в использовании на Цейлоне. Я использовал следующий дескриптор модуля, чтобы загрузить Weld из Maven Central и импортировать его в свой проект:

native("jvm")
module weldelicious "1.0.0" {
    import "org.jboss.weld.se:weld-se" "2.3.1.Final";
    import ceylon.interop.java "1.2.0";
}

import org.jboss.weld.environment.se { Weld }

shared void run() {

    value container = Weld().initialize();

    //do stuff with beans
    ...

    container.shutdown();

}

interface Receiver {
    shared formal void accept(String message);
}

import javax.inject { inject }

inject class Sender(Receiver receiver) {
    shared void send() => receiver.accept("Hello!");
}

class PrintingReceiver() satisfies Receiver {
    accept = print;
}

import org.jboss.weld.environment.se { Weld }
import ceylon.interop.java { type = javaClass }

shared void run() {

    value container = Weld().initialize();

    value sender 
            = container
                .select(type<Sender>())
                .get();

    sender.send();

    weld.shutdown();

}

value sender 
        = container
            .select(object extends TypeLiteral<Sender>(){})
            .get();

class Sender {
    Receiver receiver;
    inject shared new (Receiver receiver) {
        this.receiver = receiver;
    }
    shared void send() => receiver.accept("Hello!");
}

class Sender {
    Receiver receiver;
    inject shared new inject(Receiver receiver) {
        this.receiver = receiver;
    }
    shared void send() => receiver.accept("Hello!");
}

class Sender() {
    inject late Receiver receiver;
    shared void send() => receiver.accept("Hello!");
}

class Sender() {
    late Receiver receiver;
    inject void init(Receiver receiver) {
        this.receiver = receiver;
    }
    shared void send() => receiver.accept("Hello!");
}

import javax.enterprise.inject { produces }

produces Receiver createReceiver() 
        => object satisfies Receiver {
            accept = print;
        };

import javax.inject { qualifier }

annotation Fancy fancy() => Fancy();
final qualifier annotation class Fancy() 
        satisfies OptionalAnnotation<Fancy> {}

fancy class FancyReceiver() satisfies Receiver {
    accept(String message) 
            => print(message + " \{BALLOON}\{PARTY POPPER}");
}

//this doesn't work!
inject class Sender(fancy Receiver receiver) {
    shared void send() => receiver.accept("Hello!");
}

//this does work
class Sender {
    Receiver receiver;
    inject shared new (fancy Receiver receiver) {
        this.receiver = receiver;
    }
    shared void send() => receiver.accept("Hello!");
}

import javax.enterprise.context { applicationScoped }

applicationScoped
class PrintingReceiver() satisfies Receiver {
    accept = print;
}

<overrides xmlns="http://www.ceylon-lang.org/xsd/overrides">
    <module groupId="com.google.inject" 
         artifactId="guice" 
            version="4.0">
        <share groupId="javax.inject" 
            artifactId="javax.inject"/>
    </module>
</overrides>

native("jvm")
module guicy "1.0.0" {
    import "com.google.inject:guice" "4.0";
    import ceylon.interop.java "1.2.0";
}

import javax.inject { inject }

inject class Sender(Receiver receiver) {
    shared void send() => receiver.accept("Hello!");
}

interface Receiver {
    shared formal void accept(String message);
}

class PrintingReceiver() satisfies Receiver {
    accept = print;
}

import ceylon.interop.java {
    type = javaClass
}
import com.google.inject {
    AbstractModule,
    Guice {
        createInjector
    },
    Injector
}

Injector injector
        = createInjector(
    object extends AbstractModule() {
        shared actual void configure() {
            bind(type<Receiver>()).to(type<PrintingReceiver>());
        }
    });

import ceylon.interop.java {
    type = javaClass
}

shared void run() {
    value sender = injector.getInstance(type<Sender>());
    sender.send();
}

import com.google.inject {
    Key,
    TypeLiteral
}

shared void run() {
    value key = Key.get(object extends TypeLiteral<Sender>(){});
    value sender = injector.getInstance(key);
    sender.send();
} 

import com.google.inject {
    AbstractModule,
    Guice {
        createInjector
    },
    Injector,
    provides
}

Injector injector
        = createInjector(
    object extends AbstractModule() {
        shared actual void configure() {}
        provides Receiver createReceiver()
                => object satisfies Receiver {
                    accept = print;
                };
    });

import javax.inject { qualifier }

annotation Fancy fancy() => Fancy();
final binding annotation class Fancy() 
        satisfies OptionalAnnotation<Fancy> {}

Injector injector
        = createInjector(
    object extends AbstractModule() {
        shared actual void configure() {
            bind(type<Receiver>())
                .to(type<PrintingReceiver>());
            bind(type<Receiver>())
                .annotatedWith(Fancy()) //binding annotation
                .to(type<FancyReceiver>());
        }
    });

import com.google.inject { singleton }

singleton
class PrintingReceiver() satisfies Receiver {
    accept = print;
}