6 советов по отладке динамического кода SQL

Когда я пытаюсь бросить свой стол, я вижу:

ORA-00950: invalid DROP option

И что это говорит мне? Немного. Какой вариант, по его мнению, я дал, что это недействительно? Что я только что попытался сделать?

Если, с другой стороны, я назначаю выражение, которое я хочу выполнить, переменной, а затем вызываю EXECUTE IMMEDIATE, я могу перехватить ошибку и записать / отобразить эту переменную (см. Вторую реализацию drop_whither ниже). И тогда я мог бы увидеть что-то вроде:

DROP SYNONYMV$SQL - FAILURE

Ой! Я вижу сейчас. Я не включил пробел между типом объекта и именем объекта. Я такой глупый. Поэтому всегда объявляйте переменную, присваивайте динамически построенный оператор SQL этой переменной и выполняйте ее немедленно.

4. Всегда обрабатывайте исключение, которое может возникнуть при выполнении динамического SQL.

5. Зарегистрируйте информацию об ошибке  плюс  переменную, которую вы пытались выполнить.

Если вы не перехватите исключение, вы не сможете войти или отобразить эту переменную. Если вы не сохраните значение этой переменной, очень сложно сделать полезный отчет о проблеме в службу поддержки.

Вы ничего не можете сделать, кроме как хныкать по поводу дрянного дизайна вашего кода.

6. Постройте тестовый режим в своей подпрограмме.

Я долго писал код и портил этот код так долго, я понял, что очень полезно — особенно когда этот код вносит изменения в данные в таблицах — реализовать тестовый режим, который ничего не «делает». Просто показывает мне, что бы он сделал, если бы я позволил.

Вы можете видеть это в коде ниже, когда я передаю TRUE (по умолчанию) для параметра just_checking.

Намного лучше (?)

«?» в этом названии просто чтобы напомнить нам, что эта процедура по своей природе опасна.

Вот версия drop_wh независимо от моих рекомендаций. Обратите внимание, что для реального производственного кода вы никогда не должны   «сообщать» или «регистрировать» ошибку, вызывая DBMS_OUTPUT.PUT_LINE. Кто увидит это? Вместо этого вызовите свою стандартную процедуру регистрации ошибок, и если у вас ее нет, то получите и используйте  Logger .

PROCEDURE drop_whatever (
   nm              IN   VARCHAR2 DEFAULT '%'
 , typ             IN   VARCHAR2 DEFAULT '%'
 , just_checking   IN   BOOLEAN DEFAULT TRUE
)
AUTHID CURRENT_USER
IS
   PRAGMA AUTONOMOUS_TRANSACTION;                             
   dropstr   VARCHAR2 (32767);

   CURSOR object_cur
   IS
      SELECT object_name, object_type
        FROM user_objects
       WHERE object_name LIKE UPPER (nm)
         AND object_type LIKE UPPER (typ)
         AND object_name <> 'DROP_WHATEVER';         
BEGIN
   FOR rec IN object_cur
   LOOP
      dropstr :=
            'DROP '
         || rec.object_type
         || ' '
         || rec.object_name
         || CASE
               WHEN rec.object_type IN ('TABLE', 'OBJECT')
                  THEN ' CASCADE CONSTRAINTS'
               ELSE NULL
            END;                                              

      BEGIN
         IF just_checking
         THEN
            DBMS_OUTPUT.put_line (dropstr || ' - just checking!');
         ELSE
            EXECUTE IMMEDIATE dropstr;
            DBMS_OUTPUT.put_line (dropstr || ' - SUCCESSFUL!');
         END IF;

      EXCEPTION
         WHEN OTHERS
         THEN
            DBMS_OUTPUT.put_line (dropstr || ' - FAILURE!');
            DBMS_OUTPUT.put_line (DBMS_UTILITY.format_error_stack);
      END;
   END LOOP;
END;